#! /bin/csh -f
# format, tex and print a phone book, using the phoneformat program.
#
# Luigi Semenzato @ U.C.Berkeley, July 1986
# modified December 1987

onintr clean
set texfile = phoneout.tex
set dvifile = phoneout.dvi
set logfile = phoneout.log
set args=()
foreach i ($*)
	if ($i =~ -P*) then
		setenv PRINTER `echo $i | sed -e 's/-P//'`
	else
		set args = ($args $i)
	endif
end
	
phoneformat $args > $texfile
if ($status != 0) then
	echo "phoneformat did not produce a TeX file -- there is a problem\!"
	goto usage
endif
tex $texfile 
if (-f $dvifile) then
	lpr -d $dvifile
	/bin/rm -f $texfile $dvifile $logfile
else
	echo "TeX did not produce a dvi file -- there is a problem\!"
	exit 1
endif
exit 0

usage:
echo " usage:\
\
	printbook -R [-P<printer>] [<other options>]\
\
 for rolodex users (must have a ~/.rolodex.dat file);\
 or:\
\
	printbook [-P<printer>] [<other options>] < <filename>\
\
 for phoneformat files.  For other options, see ``phoneformat''.\

clean:
	echo "printbook: interrupted\!"
	/bin/rm -f $texfile $dvifile $logfile
	exit 1

